! Torre6
! La antorcha reacciona ahora a EMPUJA y TIRA (para hacer
! aparecer/desaparecer la puerta secreta) y otras acciones (para
! mejores mensajes de respuesta), y además se asegura de que
! no se pueda empujar dos veces seguidas, o tirar de ella dos 
! veces seguidas. Además, tiene el atributo oculto para que
! no se mencione en la lista objetos de la localidad.
!
Constant Story "La Torre^";
Constant Headline "(c) 2000 Zak y Carlos^";
Constant MANUAL_PRONOUNS;
Include "Parser";
! Aqui iría la definición de mensajes de librería.
Include "Verblib";
! Aqui irian las definiciones de las localidades
! y los objetos del juego
Object 	PuertaPrincipal "Puerta Principal"
 with   description "Estás junto a la puerta principal. 
            A su lado puedes una mesa de guardia y en la pared 
            norte hay una chimenea.",
       	e_to Dormitorio,
 has 	light;

Object 	Dormitorio "Dormitorio"
 with   description "Varios maltrechos catres se amontonan en esta 
	    habitación.",
	w_to PuertaPrincipal,
	e_to EscaleraCaracol1,
 has 	light;

Object 	EscaleraCaracol1 "Escalera de caracol"
 with 	description "El viento ulula a través de la empinada 
	    escalera de caracol, una vieja armadura parece vigilar 
	    la escalera.",
	u_to EscaleraCaracol2,
	w_to Dormitorio,
 has 	light;

Object 	Mazmorra "Mazmorra"
 with 	description "Una silenciosa estancia débilmente alumbrada 
	    por los rayos de luna que se filtran a través de un 
	    pequeño ventanuco. El suelo está lleno de paja, colgando 
	    de unos grilletes en la pared observas un esqueleto 
	    humano.",
	e_to EscaleraCaracol2,
 has 	light;

Object 	EscaleraCaracol2 "Escalera de caracol"
 with 	description [;
            print "Los desgastados peldaños de piedra resbalan en 
 	      	ocasiones. A mitad de la escalera una antorcha en la 
	      	pared impide que la oscuridad sea completa.^";
            if (EscaleraCaracol2.w_to==Mazmorra)
               	print "^Parte de la pared oeste ha deslizado 
		    mostrando una entrada.^";
        ],
   	d_to EscaleraCaracol1,
	w_to 0,
	u_to AltoTorre,
 has 	light;


Object antorcha "antorcha" EscaleraCaracol2
with   name 'antorcha',
       before [;
         Take, Turn:  "La antorcha está incrustada en la pared.";
         Blow:  "Iluso, el fuego que arde en esta antorcha no
                 es de esde mundo.";
         Push: if (EscaleraCaracol2.w_to==0) {
                     EscaleraCaracol2.w_to = Mazmorra;
                     "Al empujar la antorcha una porción de pared se
                     abre al oeste dando acceso a una estancia.";
                 }
                 else "La antorcha no cede más.";
         Pull: if (EscaleraCaracol2.w_to == Mazmorra) {
                    EscaleraCaracol2.w_to = 0;
                    "Al tirar la antorcha, la puerta secreta se cierra 
                    de nuevo.";
                 }
                 else "La antorcha no cede más.";
              ],
has female concealed;     

Object AltoTorre "Alto de la torre"
 with 	description "Una gran cama preside la estancia, los gruesos 
	    barrotes no permiten la salida por la ventana, aunque de 
	    todos modos estaría demasiado alta.",
	d_to EscaleraCaracol2,
 has 	light;

[ Initialise ;
    ! Lugar de comienzo: la puerta principal
    location=PuertaPrincipal;
    
    ! Activamos esta variable para que la descripción de los lugares
    ! se repita siempre, incluso si el jugador ya ha estado allí
    lookmode=2;

    ! Mensaje de bienvenida
    "¡¡Bienvenido a mi primer juego!!^";
];
Include "SpanishG";
! Aqui irían los verbos y acciones específicas de nuestro juego.